Jak działa funkcja LAMBDA w Excelu 365?

Poznajmy funkcję na przykładzie obliczania pola powierzchni prostokąta o bokach a oraz b.

Krok 1: Zadeklaruj nazwy zmiennych

Składnia zaczyna się od własnych nazw Twoich zmiennych, których możesz podać dowolną ilość.

=LAMBDA(a;b

Krok 2: Zadeklaruj kalkulację

W ostatnim argumencie tworzymy końcowy wzór. Co ciekawe, na liście rozwijanej z podpowiedziami Excela pojawiają się nasze zmienne.

=LAMBDA(a;b;a*b)

Krok 3: Przetestuj na 1 przykładzie

Jeżeli dla powyższego wzoru wciśniemy Enter, pojawi się błąd #OBL! gdyż Excel nie wie, co ma podstawić w miejsce a i b. Dlatego testowanie funkcji odbywa się w kolejnym nawiasie tuż za nią.

Krok 4: Umieść jako nazwę zdefiniowaną

Wydaje mi się, że posługiwanie się funkcjami jak w kroku 3. nie ma większego sensu, zwłaszcza w kontekście innej omawianej już funkcji LET, która też zadziała w tym przypadku:

=LET(a;A2;b;B2;a*b)

Celem tworzenia formuły z funkcją LAMBDA jest utworzenie nazwy zdefiniowanej, która pozwoli zapisać ją jako zdefiniowaną przez użytkownika (w danym pliku) funkcję Excela.

Zatem przechodzimy do menedżera nazw (Ctrl + F3) > Nowy > Tworzymy nową nazwę (bez spacji, znaków niedozwolonych i konfliktu z innymi nazwami Excela) > w polu Odwołuje się do umieszczamy funkcję LAMBDA.

Na koniec w nowych komórkach wstawiamy funkcję Oblicz_Pole_Prostokąta.

Tworzenie nowych funkcji było dotychczas możliwe tylko z pomocą VBA lub zewnętrznych narzędzi. Dzięki LAMBDA każdy użytkownik może stworzyć własną funkcję.

Przykład 1: Oblicz, ile jest spacji w tekście

W 1. przykładzie naszym zadaniem jest stworzenie funkcji o nazwie IleSpacji, która obliczy liczbę spacji w tekście komórki. W tym celu obliczamy, ile znaków ma cały tekst, a ile tekst, w którym nie ma spacji (usuwamy je funkcją PODSTAW).

=LAMBDA(produkt;DŁ(produkt)-DŁ(PODSTAW(produkt;" ";"")))

Funkcję wstawiamy jako nazwę zdefiniowaną, dzięki czemu w Excelu mogę użyć funkcji IleSpacji.

Przykład 2: TekstPrzed

W najbliższym czasie do Excela 365 wejdą kolejne funkcje, w tym TEXTBEFORE, czyli tekst przed separatorem. Zanim to jednak nastąpi, możemy taką funkcję stworzyć sami.

Ponieważ funkcja zwraca błąd, jeśli nie znajdzie separatora, dodajmy warunek zabezpieczający z funkcją JEŻELI.BŁĄD.

=LAMBDA(tekst;separator;JEŻELI.BŁĄD(LEWY(tekst;ZNAJDŹ(separator;tekst)-1);tekst))(A2;" ")

Na koniec tworzymy funkcję TekstPrzed.

Przykład 3: Stwórz adres e-mail

W 3. przykładzie mamy listę pracowników, składających się z imienia i nazwiska.

Naszym zadaniem jest opracować funkcję, która na podstawie tych komórek stworzy od razu adres e-mail. Założenia:

• Tekst pisany małymi literami
• Tekst bez polskich znaków
• E-mail jako imię.nazwisko@skuteczneraporty.pl
• Funkcja ma być wielokrotnego użytku i ma się nazywać UtwórzEmail

W tym przykładzie wykorzystamy możliwość rozbicia pisania miary na etapy za pomocą zmiennych, czyli funkcji LET. Dla ułatwienia zmienne będę opisywać, zaczynając od _. Każda linijka to oddzielny etap. Ostatni argument funkcji LET będzie wynikiem działania całej funkcji LAMBDA.

=LAMBDA(_Pracownik;
LET(
_PracownikMałymi;LITERY.MAŁE(_Pracownik);
_PracownikImię;TekstPrzed(_PracownikMałymi;" ");
_PracownikNazwisko;FRAGMENT.TEKSTU(_PracownikMałymi;ZNAJDŹ(" ";_PracownikMałymi)+1;DŁ(_PracownikMałymi)-ZNAJDŹ(" ";_PracownikMałymi));
_PracownikEmail;_PracownikImię&"."&_PracownikNazwisko&"@skuteczneraporty.pl";
_BezĄ;PODSTAW(_PracownikEmail;"ą";"a");
_BezĆ;PODSTAW(_BezĄ;"ć";"c");
_BezĘ;PODSTAW(_BezĆ;"ę";"e");
_BezŁ;PODSTAW(_BezĘ;"ł";"l");
_BezŃ;PODSTAW(_BezŁ;"ń";"n");
_BezÓ;PODSTAW(_BezŃ;"ó";"o");
_BezŚ;PODSTAW(_BezÓ;"ś";"s");
_BezŻ;PODSTAW(_BezŚ;"ż";"z");
_BezŹ;PODSTAW(_BezŻ;"ź";"z");
_BezŹ))(A2)

Na koniec dodajemy funkcję jako nazwę zdefiniowaną i oddajemy w ręce użytkownika jako funkcję UtwórzEmail.

Podsumowanie funkcji LAMBDA

Podsumowując, nowa funkcja LAMBDA wraz z funkcją LET może stać się Twoim nowym orężem w tworzeniu zaawansowanych rozwiązań, z których później korzystać będą zwykli użytkownicy. Możesz też spodziewać się plików, w których nowoczesny użytkownik Excela 365 dostarczy Ci rozwiązanie właśnie w takiej postaci. Jeśli dodać do tego odmienioną w Excelu 365 pracę na formułach tablicowych (i zbliżające się nowe funkcje w tym zakresie), otrzymujemy pakiet funkcjonalności, obok których żaden użytkownik Excela 365 nie może przejść obojętnie.

Plik do pobrania

Tu możesz pobrać plik i przetestować nową funkcję LAMBDA w Excelu 365.

Składnia funkcji LET

=LET(Nazwa1;Wartość_nazwy1;[Nazwa2;Wartość_nazwy2];[…]; Obliczenie)

Funkcja LET ma nieparzystą liczbę argumentów. Najpierw parami podajemy:

• wymyśloną przez nas nazwę zmiennej,
• przypisaną do zmiennej wartość lub formułę.

Maksymalnie można zdefiniować 126 zmiennych w jednej funkcji.

Ostatnim argumentem funkcji LET jest formuła do obliczenia.

Korzyści stosowania funkcji LET

• Zwiększona szybkość działania formuł – Funkcja LET wartość zmiennej oblicza tylko raz. Bez tej funkcji to samo wyrażenie było obliczane wiele razy.
• Łatwe czytanie i edytowanie – W tej funkcji od razu widać co jest zapamiętane pod daną nazwą (zmienną). Nie trzeba też kopiować i wklejać tego samego wyrażenia w formule. Dzięki temu formuła jest krótsza i prostsza.

Jeśli Twoja formuła jest mocno złożona, polecam użyć LET i rozbić dodatkowo formułę na wiele wierszy – ręcznie (Alt+Enter) lub automatycznie poprzez stronę Excel Formula Beautifier.

Przykład 1: Oblicz wielomian

Policz wartość wielomianu x⁴ + 3x² – 2x + 9 dla x = 5.

Rozwiązanie:

=LET(x;5;x^4+3*x^2-2*x+9)

Przykład 2: Oblicz równanie

Oblicz pierwiastek z a^2 + b^2, gdzie a = 7 i b = 8.

Rozwiązanie:

=LET(a;7;b;8;PIERWIASTEK(a^2+b^2))

Przykład 3: Użyj FILTRUJ bez 0

Funkcja LET może też operować na tablicach. Przefiltruj poniższą tabelę wyświetlając zamówienia o wybranym priorytecie.

Za pomocą funkcji FILTRUJ można to zrobić tak:

Formuła w G5:

=FILTRUJ(A2:D21;B2:B21=H2)

Minus tego rozwiązania jest taki, że zamiast pustych komórek pojawiły się zera.

Lepsze rozwiązanie z użyciem funkcji LET:

Funkcja w komórce L5:

=LET(wynik;FILTRUJ(A2:D21;B2:B21=M2);JEŻELI(wynik=0;"";wynik))

Przykład 4: Sprawdź, czy dane zamówienie jest pilne, czyli jego priorytet jest krytyczny lub nieokreślony

Rozwiązanie bez użycia funkcji LET (w komórce G2) z funkcją Excela 365 WARUNKI:

=WARUNKI(

WYSZUKAJ.PIONOWO(F2;$A$1:$C$9427;3;0)="krytyczny";"PILNE";

WYSZUKAJ.PIONOWO(F2;$A$1:$C$9427;3;0)="nieokreślony";"PILNE";

PRAWDA;"nie"

)

Można tą formułę skrócić używając funkcji LET. Zauważmy, że funkcja WYSZUKAJ.PIONOWO powtarza się dwa razy. Przypiszemy jej więc nazwę p:

=LET(

p;WYSZUKAJ.PIONOWO(F2;$A$1:$C$9427;3;0);

WARUNKI(p="krytyczny";"PILNE";p="nieokreślony";"PILNE";PRAWDA;"nie")

)

Przykład 5: Usuń wszystkie cyfry z tekstu wpisanego do komórki

Wyjściowa formuła w komórce B2:

=POŁĄCZ.TEKSTY("";PRAWDA;JEŻELI(CZY.BŁ(FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0);FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1);""))

Działa ona w Excelu 365 jako formuła tablicowa (we wcześniejszych wersjach zatwierdzamy ją klawiszami Ctrl+Shift+Enter). W Excelu 365 możemy skrócić tę formułę, używając nowej funkcji SEKWENCJA. Formułę tą wpiszmy do komórki C2:

=POŁĄCZ.TEKSTY("";PRAWDA;JEŻELI(CZY.BŁ(FRAGMENT.TEKSTU(A2;SEKWENCJA(DŁ(A2));1)+0);FRAGMENT.TEKSTU(A2;SEKWENCJA(DŁ(A2));1);""))

I teraz wykorzystamy naszą funkcję LET. Powtarzający się fragment formuły „SEKWENCJA(DŁ(A2))” nazwiemy słowem „nazwa”. Formułę wpiszemy do D2:

=LET(nazwa;SEKWENCJA(DŁ(A2));POŁĄCZ.TEKSTY("";PRAWDA;JEŻELI(CZY.BŁ(FRAGMENT.TEKSTU(A2;nazwa;1)+0);FRAGMENT.TEKSTU(A2;nazwa;1);"")))

Ale to nie koniec! Tak jak inne funkcje, funkcję LET można zagnieżdżać. Argumenty z zewnętrznego LET mogą być używane wewnątrz LET niższego poziomu. Zauważmy, że funkcja „FRAGMENT.TEKSTU(A2;nazwa;1)” pojawia się tu dwukrotnie. Ten kawałek formuły nazwiemy „fr” i otrzymujemy (w komórce E2):

=LET(nazwa;SEKWENCJA(DŁ(A2));LET(fr;FRAGMENT.TEKSTU(A2;nazwa;1);POŁĄCZ.TEKSTY("";PRAWDA;JEŻELI(CZY.BŁ(fr+0);fr;""))))

Tworząc tą formułę możemy zauważyć, że nazwy zdefiniowane w funkcji LET pojawiają się na liście rozwijanej obok funkcji i można je szybciej wprowadzić za pomocą myszy lub klawisza TAB:

Pobierz plik Excel z przykładami i sprawdź działanie funkcji LET w Excelu 365

Tu możesz pobrać plik Excel z przykładami funkcji LET.

Podoba Ci się formuła LET?

Jeśli znajdziesz jakieś praktyczne zastosowanie funkcji LET, pochwal się nim.